/////////////////////////////////////////////////////////////////////
// "On the torsion of rational elliptic curves over sextic fields" //
//        Harris B. Daniels and Enrique González-Jiménez           //
/////////////////////////////////////////////////////////////////////

// 2/8/2018 - Magma 2.23

// Magma script related to Proposition 8 (j) 


//f1 is the j-map from X_0(3) to P1 taken from Zywina, On the possible images of the 
//mod l representations associated to elliptic curves over Q.
//f2 is the j-map from X_{20} to P1 taken from Rouse, Zureick-Brown, Elliptic curves 
//over $\Q$ and $2$-adic images of Galois.

F<t> := FunctionField(Rationals());
f1 := 27*(t+1)*(t+9)^3*t^-3; //the j-map for X0(3)
f2 := (-4*t^8 + 32*t^7 + 80*t^6 - 288*t^5 - 504*t^4 + 864*t^3 + 1296*t^2 - 864*t - 1188)/(t^4 + 4*t^3 + 6*t^2 + 4*t + 1);
R<x,y>:=PolynomialRing(Rationals(),2);
g:=Numerator(Evaluate(f1,x)-Evaluate(f2,y));
assert IsIrreducible(g);
C<X,Y,Z>:=ProjectiveClosure(Curve(AffineSpace(R),g)); //
assert Genus(C) eq 1;
P := C![0,1,0];
E,map := EllipticCurve(C,P);
assert Rank(E) eq 0;
assert CremonaReference(E) eq "48a3";


T,mp := TorsionSubgroup(E);
PTS := [mp(t) : t in T];

//Pull back the torsion points and add the presages to Set.
Set := {};
PHI := map;
for p in PTS do
Set := Set join RationalPoints(p @@ PHI);
end for;
assert Set eq { C![-4/3, 7, 1], C![0, -1, 1], C![0, 1, 0], C![-3/4, -5, 1], C![-3/4, -1/2, 1], C![1, 0, 0], C![-4/3, -5/4, 1] };


/*
Thus there are 4 non-sinqular points ([-4/3, 7, 1], [-4/3, -5/4, 1], [-3/4, -5, 1], [-3/4, -1/2, 1] ),  singular point ( [0, -1, 1] ) and cusps at infinity ( [0, 1, 0], [1, 0, 0] )
*/

//Check that the j-maps agree here.
assert Evaluate(f1,-4/3) eq Evaluate(f2,7);
assert Evaluate(f1,-4/3) eq Evaluate(f2,-5/4);
assert Evaluate(f1,-3/4) eq Evaluate(f2,-5);
assert Evaluate(f1,-3/4) eq Evaluate(f2,-1/2);

//There are two j invariants they are 109503/64 and -35937/4 
assert [Evaluate(f1,-4/3), Evaluate(f1,-3/4)] eq [ 109503/64, -35937/4 ];
    

//For each of these j-invariants from Zywina there are unique twists that have a 
//rational point of order 3. These curves have G_E(3) equal to 3B.1.1. Using the fine 
//models in Zywina, On the possible images of the mod l representations associated to 
//elliptic curves over Q, we compute each curve.
At := -3*(t+1)^3*(t+9);
Bt := -2*(t+1)^4*(t^2-18*t-27);

A1 := Evaluate(At, -4/3);
B1 := Evaluate(Bt, -4/3);

A2 := Evaluate(At, -3/4);
B2 := Evaluate(Bt, -3/4);

E1 := EllipticCurve([A1,B1]);
E2 := EllipticCurve([A2,B2]);

//Sanity check that we entered the model correctly.
assert #TorsionSubgroup(E1) eq 3;
assert #TorsionSubgroup(E2) eq 3;

//Check that we got the curves we claimed we did. 
assert CremonaReference(E1) eq "162d1";
assert CremonaReference(E2) eq "162a1";

//Compute the torsion subgroups of the elliptic curves over their 3-division fields 
//to see we do not get a point of order 4.
P<x> := PolynomialRing(Rationals());
f1 := x^6+3;
f2 := x^6-3*x^5+5*x^3-3*x+1;
K1 := NumberField(f1);
K2 := NumberField(f2);
EK1 := ChangeRing(E1,K1);
EK2 := ChangeRing(E2,K2);
T1 := TorsionSubgroup(EK1);
T2 := TorsionSubgroup(EK2);

//Check that both these curves have torsion (3,3) over the given sextic fields.
assert IsIsomorphic(T1,AbelianGroup([3,3]));
assert IsIsomorphic(T2,AbelianGroup([3,3]));